乘风原创程序

  • ASP Eval、Execute、ExecuteGlobal区别分析
  • 2020/3/29 0:14:22
  • Eval 计算一个表达式的值并返回结果。

    语法:[result = ]eval_r(expression_r)

    expression_r 为任意有效 VBScript 表达式的字符串

    示例:

    response.Write(eval_r("3+2")) '输出 5 

    "3+2" 使用引号括起来,表示是一个字符串,但是在 Eval “眼里”,把它当作一个表达式 3+2 来执行。

    <%
    a=1
    b=2
    response.write "a+b"   '会直接输出 a+b
    response.write eval("a+b") '会计算具体的结果 输出3
     
    '在使用eval的时候,eval会尽可的把内容里的换成程序里出现的变量,然后计算出结果并返回
    %>
    

    Execute 执行一个或多个指定的语句。多个语句间用冒号(:)隔开。

    execute : 用来执行一句或多句的代码,不一定有返回的结果

    语法:Execute statements

    示例:

    Execute "response.Write(""abc"")" '输出 abc
    "response.Write(""abc"")" 使用引号括起来,表示是一个字符串

    但是在 Execute “眼里”,把它当作一个语句 response.Write("abc") 来执行。

    '比如我们有时候需要动态声明一个或多个的变量:
    
    Dim Str : Str="UserName,Password,LoginTime"
    execute("Dim "&Str)
    

    有的人可能要说了,在ASP里,变量声明不声明其实区别不大的,但实际上不是这样的,比如下面这样一段代码:

    <%
    Sub GetData()
        UserName="脚本之家"
        LoginTime="2020-3-29"
    End Sub
    Dim UserName,LoginTime '先声明变量
    Call GetData()    '再调用sub过程
    Response.write UserName  '这时才能输出具体的值,如果不事先声明变量的话,就会输出空
    %>

     再来看一个具体的实例,了解eval和execute的区别和用法:

    第一个实例:

    '假如我们有这样一个sub过程:
    Sub OutTime()
        response.write now()
    End Sub
     
    '那么在我们要动态调用这个SUB过程的时候,只能用execute:
    execute("OutTime")
    '或者
    execute("OutTime()")
     
    '如果在这个时候用eval,就会报错,因为OutTime过程里,没有返回值

    第二个实例:

    Function GetTime()
        GetTime=now()
    End Function
     
    '上面这个函数,我们要动态调用的话,只能用eval,如果用execute,不会报错,但也获取不到具体的内容:
    execute("GetTime()")
    response.write execute("GetTime()") 
    '上面这两种写法,站长都已亲测,输出的都是空白
     
    response.write eval("GetTime()")
    response.write eval("GetTime")
    '上面这两种写法 才能正确的输出内容

    ExecuteGlobal 在全局名字空间中执行一个或多个指定的语句。
    语法:ExecuteGlobal statement
    示例:

    dim c 
    c = "全局变量" 
    sub S1() 
    dim c 
    c = "局部变量" 
    Execute "response.Write(c)" '输出 局部变量 
    ExecuteGlobal "response.Write(c)" '输出 全局变量 
    end sub 
    Execute "response.Write(c)" '输出 全局变量 
    call S1() 

    变量 c 既在全局范围内定义,也在函数范围内定义,Execute 按自己所处的位置来决定使用局部变量还是全局变量,而 ExecuteGlobal 则始终只认全局范围的 c。

    总结:

    Eval 只执行一个语句 语句可以有也可以没有返回值
    Execute 执行一个或多个语句 忽略语句的返回值
    ExecuteGlobal 执行一个或多个语句 忽略语句的返回值 全局变量和局部变量同名时总是使用全局变量

    注意:
    在 VBScript 中“赋值”与“比较”都是使用“=”,比如“a=b”既可以说是将 b 值赋予 a,也可以说是判断 a 与 b 是否相等,那么 eval_r("a=b") 是表示赋值还是比较运算呢?
    这里有个约定,在 Eval 中,“a=b”总是表示比较运算,在 Execute 和 ExecuteGlobal 中,总是表示赋值。